#!/bin/csh -f

# ..If no args print Usage message
if ($#argv == 0) then
	goto usage
endif

umask 000

# ..Set defaults
set wdir=/ptmp/$USER/ERA40

# ..Parse arguments
set remargs = ""
while ($#argv > 0)
	switch ("$1")

	case  "-h":
		goto usage

	case  "-d":
		shift
		set wdir=$1
		breaksw

	case  "-d*":
		set wdir = `echo $1 | cut -c3-`
		breaksw

	case  "-i":
		shift
		set istrt=$1
		breaksw

	case  "-i*":
		set istrt = `echo $1 | cut -c3-`
		breaksw

	case  "-n":
		shift
		set nyrs=$1
		breaksw

	case  "-n*":
		set nyrs = `echo $1 | cut -c3-`
		breaksw

	default:
		set remargs=($remargs $1)
		breaksw
	endsw
	shift
end
if ($remargs != "") then
	echo
	echo "Arguments not recognized: "${remargs}
	echo
	exit(2)
endif

# ..Invoke associated NCL script
setenv DS120 "${istrt};${nyrs};${wdir}"
( ncl /home/tempest/mai/svn/datasets/ECMWF/ds120.0.ncl >! ds120.0.out ) >&! ds120.0.err

exit($status)

usage:
	echo
	echo " Usage:"
	echo "  ds120.0.csh -i start_year -n nyrs [-d working_dir]"
	echo
	echo " Years available: 1958-2001"
	echo
	echo " Working directory defaults to /ptmp/$USER/ERA40"
	echo
	exit(1)