// Example HOPS script #1
// atm_plot: Plotting atmospheric data

// Open winter (DJF) mean ECMWF analysis data (1986-1992)
// interpolated to the T42, 18-level hybrid sigma-pressure CCM2 grid
// (converted to CSM netCDF format using Brian Eaton"s ccm2nc)

hopen,"/data/svn/ccm3/ET42DJF8692.nc";

// Get temperature (T) and zonal wind (U) for first sample
T= hget("T",t=1,subscript=1);
U= hget("U",t=1,subscript=1);

// Compute zonal-average temperature and zonal wind
TBAR= hsub(T,x="avg");
UBAR= hsub(U,x="avg");

// Plot zonal averages
hplot, TBAR, fill=1;
hplot, UBAR, fill=1;

// Compute eddy temperature by subtracting zonal-mean
TPRIME= hop(T,"-",TBAR);

// Plot zonal standard deviation of eddy temperature field
hplot, hsub(TPRIME,x="rms"), fill=1, overlay=1;

// Extract and plot surface pressure
PS= hget("PS",t=1,subscript=1);
hplot, PS, fill=1;

// Restrict surface pressure to North Atlantic domain, and plot it
PSA=hsub(PS,limx=[-80,20],limy=[30,75],rotx=180);
hplot, PSA, fill=1;

// Compute pressure values on the hybrid sigma-pressure surfaces
P= hcoord(T,"z");

// Plot pressure values at the top and bottom levels
hplot, hsub(P,z=1,subscript=1);
hplot, hsub(P,z=18,subscript=1);