// Example HOPS script #6
// reanal_z500: Analyze 500 hPa height in NMC re-analysis data

// Open 23 years of monthly-mean NMC re-analysis data (1973-1995)
// for selected variables
// (This file is stored in fern/winterpark in the /tmp space)

hopen,"/tmp/svn/csm/REANAL/h23-1973.nc";

// Extract the 500 hPa height field for all months
Z500= hget("ZA", z=500);
Z500.name= "Z500";

// Fold time dimension to create an i-dimension corresponding
// to the 12 calendar months
Z500= hfold( Z500, month1="jan");

// Display all the date values
print, *Z500.date;

// Plot height field for February 1981, using NH polar stereographic projection
hplot, hsub(Z500,t=810101,i="feb"), proj="nhp";

// Compute time-average (for each month separately)
Z500AVG= hsub(Z500,t="avg");

// Plot average height field for February
hplot, hsub(Z500AVG,i="feb"), proj="nhp";

// Compute monthly height anomlies (by subtracting time average)
Z500ANOM= hop( Z500, "-", Z500AVG );

// Compute standard deviation of height anomalies
Z500RMS= hsub(Z500ANOM,t="rms");

// Plot height standard deviation for February
hplot, hsub(Z500RMS,i="feb"), proj="nhp";

// Save mean, standard deviation, and anomaly time-series for height field
Z500AVG.name= "Z500AVG";
Z500RMS.name= "Z500RMS";
Z500ANOM.name= "Z500ANOM";

hsave, "z500y1973-95.nc", Z500AVG, Z500RMS, Z500ANOM;